saving TPrintview as JPEG, BMP, TIFF

[LarryK]

TPrintview
THANK YOU for creating such a terrific component.
I use it to create medical notes because my handwriting is illegible. Really.

I would like to save the TPrintview document to a file that my Turbopower APRO fax server can poll and fax out later in the day, but APRO fax only can load/fax files in BMP, TIFF, JPEG formats.

Can you point me to a source for a component to save the TPrintview document in any of these formats. Thanks

Larry

[Radagast]

Can't you simply create bitmap (TBitmap I think) and rewrite all text from this component to it? Or set constant size and position and use screenshot? Maybe these are stupid questions but I haven't seen this component yet.

[LarryK]

The reason I am using tPrintview is because my document is a very complex compound document with images, frames with different sized text and the like. And, once created, there is no procedure like SaveToBitmapFile.

[Radagast]

I've downloaded it and I'll look at it. But I really think that screenshot or something like that should work. Or if you can print it (and I think it is made for this) you can print it into pdf file, so maybe there's also option to print to bitmap. You should try in system options (or search for program to printng into bmp).

[Kambiz]

Async Pro has a fax driver, which you can use it to directly print documents on the virtual fax.

In the other hand, you can use the Pages property of PrintPreview to convert each page (which is a metafile) to a bitmap and/or jpeg image.

[LarryK]

Thanks Kambiz - - - but converting the pages to jpeg is exactly the step I want, but don't know how to do !

Printing to the fax driver forces a dialog to pop up and the application I am working on will store documents created during the day and fax them out, unattended, at night with no users in the building.


Larry.

[Kambiz]

I hope the following code be helpful.

Code: Select all

procedure SavePreviewPageAsBitmap(Preview: TPrintPreview;
  PageNo: Integer; const FileName: String);
var
  Metafile: TMetafile;
  Bitmap: TBitmap;
  JPEG: TJPEGImage;
begin
  Metafile := Preview.Pages[PageNo];
  if Metafile <> nil then
  begin
    Bitmap := TBitmap.Create;
    try
      Bitmap.Width := Metafile.Width;
      Bitmap.Height := Metafile.Height;
      Bitmap.Canvas.Draw(0, 0, Metafile);
      Bitmap.SaveToFile(FileName);
    finally
      Bitmap.Free;
    end;
  end;
end;

procedure SavePreviewPageAsJpeg(Preview: TPrintPreview;
  PageNo: Integer; const FileName: String);
var
  Metafile: TMetafile;
  Bitmap: TBitmap;
  JPEG: TJPEGImage;
begin
  Metafile := Preview.Pages[PageNo];
  if Metafile <> nil then
  begin
    Bitmap := TBitmap.Create;
    try
      Bitmap.Width := Metafile.Width;
      Bitmap.Height := Metafile.Height;
      Bitmap.Canvas.Draw(0, 0, Metafile);
      JPEG := TJPEGImage.Create;
      try
        JPEG.Assign(Bitmap);
        JPEG.JPEGNeeded;
        JPEG.SaveToFile(FileName);
      finally
        JPEG.Free;
      end;
    finally
      Bitmap.Free;
    end;
  end;
end;

procedure TMainForm.Button1Click(Sender: TObject);
begin
  SavePreviewPageAsBitmap(PrintPreview, 1, 'C:\test.bmp');
  SavePreviewPageAsJpeg(PrintPreview, 1, 'C:\test.jpg');
end;

[LarryK]

T H A N K Y O U K A M B I Z ! ! !
I really appreciate the example code.
It will take me a few weeks to work it into my existing program.....coding is not my "day job"

Larry.